UWSC

コード作成中に必要な基本情報取得[UWSC]

公開済み 2012年11月11日 · 更新済み 2012年11月11日

// 対象ウィンドウタイトル = "ttstpqbf フィルタ"
// 対象ウィンドウID = ウィンドウID取得(対象ウィンドウタイトル)

対象ウィンドウタイトル = STATUS(0, ST_TITLE)
対象ウィンドウID = ウィンドウID取得(対象ウィンドウタイトル)

// 状態表示
print 対象ウィンドウタイトル  //タイトル表示
print "X=" + STATUS(対象ウィンドウID, ST_X) + ",Y=" + STATUS(対象ウィンドウID, ST_Y)
print "幅=" + STATUS(対象ウィンドウID, ST_WIDTH) + ",高=" + STATUS(対象ウィンドウID, ST_HEIGHT)
print "IsICON=" + STATUS(対象ウィンドウID, ST_ICON)
print "IsVISIBLE=" + STATUS(対象ウィンドウID, ST_VISIBLE)
print "IsACTIVE=" + STATUS(対象ウィンドウID, ST_ACTIVE)

// タブを全て表示する
print
print "[タブ]"
for i = 0 to GetItem(対象ウィンドウID, ITM_TAB, 1) - 1
	タブ名 = ALL_ITEM_LIST[i]
	タブ状態 = CHKBTN(対象ウィンドウID, タブ名)
	print "[" + i + "] " + タブ名 + " (" + タブ状態 + ")"
next

// エディットボックスを全て表示する
print
print "[エディット]"
for i = 0 to GetItem(対象ウィンドウID, ITM_EDIT, 1) - 1
	エディット名 = ALL_ITEM_LIST[i]
	エディット状態 = GETSTR(対象ウィンドウID, i, 0)
	print "[" + i + "] " + エディット名 + " (" + エディット状態 + ")"
next

// ボタンを全て表示する
print
print "[ボタン]"
for i = 0 to GetItem(対象ウィンドウID, ITM_BTN, 1) - 1
	ボタン名 = ALL_ITEM_LIST[i]
	ボタン状態 = CHKBTN(対象ウィンドウID, ボタン名)
	print "[" + i + "] " + ボタン名 + " (" + ボタン状態 + ")"
next

// リストを全て表示する
print
print "[リスト]"
for i = 0 to GetItem(対象ウィンドウID, ITM_LIST, 1) - 1
	リスト名 = ALL_ITEM_LIST[i]
	print "[" + i + "] " + リスト名
next

// メニューを全て表示する
print
print "[メニュー]"
for i = 0 to GetItem(対象ウィンドウID, ITM_MENU, 1) - 1
	メニュー名 = ALL_ITEM_LIST[i]
	print "[" + i + "] " + メニュー名
next

// スタティックを全て表示する。
print
print "[スタティック]"
for i = 0 to GetItem(対象ウィンドウID, ITM_STATIC, 1) - 1
	print "[" + i + "] " + ALL_ITEM_LIST[i]
next

// フォーカス/マウスポインタ情報
FOCUS_STR = GETSTR(対象ウィンドウID)
W_MOUSE_X = G_MOUSE_X - STATUS(対象ウィンドウID, ST_X)
W_MOUSE_Y = G_MOUSE_Y - STATUS(対象ウィンドウID, ST_Y)
print
print "[フォーカス/マウスポインタ]"
print "フォーカス : " + FOCUS_STR
print "絶対位置 : X=" + G_MOUSE_X + ",Y=" + G_MOUSE_Y
print "相対位置 : X=" + W_MOUSE_X + ",Y=" + W_MOUSE_Y
print "ポインタ : " + MUSCUR()
print "ポインタ下の色 : " + PEEKCOLOR(G_MOUSE_X, G_MOUSE_Y)

// ----- セッションのウィンドウID取得 -----
function ウィンドウID取得(ウィンドウタイトル)
	ID = GETID(ウィンドウタイトル, , 0)
	ifb ID < 0
		print "ウィンドウ '" + ウィンドウタイトル + "' が見つかりません。";
		exitexit
	endif
	タイトル = STATUS(ID, ST_TITLE)
	print "ウィンドウID取得 : " + ID + " (" + タイトル + ")"
	Result = ID
fend